Avi dosya bulma

[zengin]

s.a

Degerli arkadaşlarım Media Player Avi dosyasını Dosya Klasörü icinde aramak istiyorum
Bunu DirectoryExists ile denedim fakat Bulamıyor bana Bu konuda yardımcı olursanız Sevinirim

[conari]

Kod: Tümünü seç

implementation
....


// Recursive procedure to build a list of files
procedure FindFiles(FilesList: TStringList; StartDir, FileMask: string);
var
  SR: TSearchRec;
  DirList: TStringList;
  IsFound: Boolean;
  i: integer;
begin
  if StartDir[length(StartDir)] <> '\' then
    StartDir := StartDir + '\';

  { Build a list of the files in directory StartDir
     (not the directories!)                         }

  IsFound :=
    FindFirst(StartDir+FileMask, faAnyFile-faDirectory, SR) = 0;
  while IsFound do begin
    FilesList.Add(StartDir + SR.Name);
    IsFound := FindNext(SR) = 0;
  end;
  FindClose(SR);

  // Build a list of subdirectories
  DirList := TStringList.Create;
  IsFound := FindFirst(StartDir+'*.*', faAnyFile, SR) = 0;
  while IsFound do begin
    if ((SR.Attr and faDirectory) <> 0) and
         (SR.Name[1] <> '.') then
      DirList.Add(StartDir + SR.Name);
    IsFound := FindNext(SR) = 0;
  end;
  FindClose(SR);

  // Scan the list of subdirectories
  for i := 0 to DirList.Count - 1 do
    FindFiles(FilesList, DirList[i], FileMask);

  DirList.Free;
end;

// Example: how to use FindFiles
procedure TForm1.ButtonFindClick(Sender: TObject);
var
  FilesList: TStringList;
begin
  FilesList := TStringList.Create;
  try
    FindFiles(FilesList, EditStartDir.Text, EditFileMask.Text);
    ListBox1.Items.Assign(FilesList);
    LabelCount.Caption := 'Files found: ' + IntToStr(FilesList.Count);
  finally 
    FilesList.Free;
  end;
end;

[zengin]

üstadım sonuc alamıyorum

[conari]

Kod: Tümünü seç

FindFiles(FilesList, EditStartDir.Text, EditFileMask.Text);

Örnek;
EditStartDir.Text = C:\

EditFileMask.Text= *.Avi
yazman yeterli.

[zengin]

conari arkadaşımın önerdigi Saglıklı calışan kod

Kod: Tümünü seç

procedure TForm1.Button4Click(Sender: TObject);
var
  FilesList: TStringList;
  Yol : string;
begin
    Yol:= GetCurrentDir;
    FilesList := TStringList.Create;
  try
    FindFiles(FilesList, yol, Edit1.Text+'*.Avi');//burasını ilave edince calıştı
    ListBox1.Items.Assign(FilesList);
    Label1.Caption := 'Files found: ' + IntToStr(FilesList.Count);
  finally
    FilesList.Free;
  end;
  
end;

Üstadım cok teşekkür ederim iyi calışmalar