Mouse Pozisyonu Hakkında [Çözüldü]

[xozcanx]

Kod: Tümünü seç

procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  Caption:=IntToStr(x)+'-'+IntToStr(y);
end;

Merhaba;
Yukarıdaki kod ile Form üzerindeki mousen pozisyonunu bulabiliyoruz. Fakat form üzerine bir TPanel varsa ve Aling =AlClient ise mouse pozisyonunu alamıyoruz. Genel olarak Form üzerindeki Mouse kordinatlarına nasıl ulaşabiliriz.

Teşekkürler.

[G.Arkas]

Aynı kodu Panelin MouseMove eventine yazarsan istediğini alırsın. basit mantık!

[xozcanx]

Aynı kodu Panelin MouseMove eventine yazarsan istediğini alırsın. basit mantık!

Merhaba;
Kusura bakmayın soru eksik oldu sanırım.
MouseMove eventi olan tüm nesnelerde yukarıdaki kod çalışıyor fakat örnek olarak TWebBrowser üzerinde yapamıyoruz. Yada 3. parti bir bileşen varsa ve yine MouseMove Eventi yoksa yukarıdaki kod çalışmıyor. Farklı bir yöntem olarak ne izleyebiliriz?

Teşekkürler.

[SimaWB]

Windows'un WM_SETCURSOR mesajını yakalayıp işleyebilirsiniz:

Kod: Tümünü seç

private
  procedure WMSetCursor(var Msg: TWMSetCursor); message WM_SETCURSOR;

Kod: Tümünü seç

procedure TForm1.WMSetCursor(var Msg: TWMSetCursor);
var
  p: TPoint;
begin
  inherited;
  GetCursorPos(p);
  Caption := Format('X:%d,   Y:%d', [p.X, p.Y]);
end;

[SimaWB]

Bir ekleme yapayım, belki işinize yarar: Eğer mouse'un hangi bileşen üzerinde olduğunu tespit etmek isterseniz FindVCLWindow(p) size bileşeni döndürür:

Kod: Tümünü seç

var
  p: TPoint;
  C: TWinControl;
begin
  inherited;
  GetCursorPos(p);
  C := FindVCLWindow(p);
  if Assigned(C) then
    Caption := C.Name;
end;

[xozcanx]

Windows'un WM_SETCURSOR mesajını yakalayıp işleyebilirsiniz:

Kod: Tümünü seç

private
  procedure WMSetCursor(var Msg: TWMSetCursor); message WM_SETCURSOR;

Kod: Tümünü seç

procedure TForm1.WMSetCursor(var Msg: TWMSetCursor);
var
  p: TPoint;
begin
  inherited;
  GetCursorPos(p);
  Caption := Format('X:%d,   Y:%d', [p.X, p.Y]);
end;

Bir ekleme yapayım, belki işinize yarar: Eğer mouse'un hangi bileşen üzerinde olduğunu tespit etmek isterseniz FindVCLWindow(p) size bileşeni döndürür:

Kod: Tümünü seç

var
  p: TPoint;
  C: TWinControl;
begin
  inherited;
  GetCursorPos(p);
  C := FindVCLWindow(p);
  if Assigned(C) then
    Caption := C.Name;
end;

Hocam cevabınız ve ilginiz için Teşekkürler.
Form üzerinde Groupbox,Memo,Panel,Edit,Button hangisinin üzerine gelirsem geleyim Procedure işe yarıyor.Süper!
Fakat ikinci mesajımda verdiğim örnekteki gibi WebBrowser üzerine geldiğimde işlemiyor.

[esistem]

Selam;

Kod: Tümünü seç

procedure TForm1.Timer1Timer(Sender: TObject);
begin
label1.Caption:=inttostr(mouse.CursorPos.x)+' / '+inttostr(mouse.CursorPos.y);
end;

Yukarıdaki kod tüm ekrandaki mouse pozisyonunu verir. Sen formun left ve top unu baz alarak formda hangi koordinatlarda olduğunu bulabilirsin.

[mrmarman]

WebBrowser boş iken Delphi'ye aittir ama herhangi bir sayfa Navigate edildiğinde bu durum farklılaşır.

Aşağıda iki farklı yöntem önereceğim. Her ikisi de çalışacaktır.
1. Yöntem forma bir tane Timer koyup bağımsızlaştırma

Kod: Tümünü seç

procedure TForm1.Timer1Timer(Sender: TObject);
var
  p, p2: TPoint;
  iGenelX, iGenelY,
  wbX, wbY : Integer;
begin
    GetCursorPos(p); // Burası tüm Windows odaklı sonuç verir.
    p2 := ScreenToClient( p ); // Burası Formunun iç kısmına odaklı sonuç verir.
    iGenelX := p2.X;
    iGenelY := p2.Y;
    wbX := iGenelX - WebBrowser1.Left;
    wbY := iGenelY - WebBrowser1.Top;
    Caption := Format('X:%d,Y:%d üzerinden WebBrowser X:%d,Y:%d', [iGenelX, iGenelY, wbX, wbY]);
end;

2.Yöntem sistem mesajlarından yola çıkarak Mouse takip

Kod: Tümünü seç

  private
    procedure AppMsg(var Msg: TagMsg; var Handled: Boolean);

procedure TForm1.FormCreate(Sender: TObject);
begin
  WebBrowser1.Navigate('http://www.google.com.tr');
  Application.OnMessage   :=   AppMsg;
end;

procedure TForm1.AppMsg(var Msg: TagMsg; var Handled: Boolean);
var
  p, p2: TPoint;
  iGenelX, iGenelY,
  wbX, wbY : Integer;
begin
  if  Msg.Message = WM_MOUSEMOVE then
  begin
    GetCursorPos(p); // Burası tüm Windows odaklı sonuç verir.
    p2 := ScreenToClient( p ); // Burası Formunun iç kısmına odaklı sonuç verir.
    iGenelX := p2.X;
    iGenelY := p2.Y;
    wbX := iGenelX - WebBrowser1.Left;
    wbY := iGenelY - WebBrowser1.Top;
    Caption := Format('X:%d,Y:%d üzerinden WebBrowser X:%d,Y:%d', [iGenelX, iGenelY, wbX, wbY]);

    Handled := True;
  end;
end;

[xozcanx]

mrmarman ve esistem verdiğiniz bilgiler için teşekkürler.
Timer Kullanımı değil de Procedure olarak kullandım ve istediğim sonucu aldım.
Cevabın açıklayıcı ve öğretici olması çok güzel olmuş.

İyi Çalışmlar.