Event atama hakkında [Çözüldü]

[adelphiforumz]

Selamlar

Aşağıdaki şekilde ClientSocket nesne'sinin onWrite Events özelliğine atama yapmak istiyorum.
Fakat derlemede hata alıyorum nedeni hakkında yardımcı olabilirmisiniz.

Teşekkürler

Kod: Tümünü seç

unit untEntitys;

interface
uses
  Windows, Messages, Math, SysUtils, Variants, Classes, Graphics, Controls, TypInfo, Forms,
  Dialogs, Menus, DB, ADODB, StdCtrls, cxGridCustomView, Buttons, ComCtrls, clipbrd,  
  System.Win.ScktComp;
...
...
 ...
Type
  TEntitys = Class
  public
    procedure prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
  End;
implementation
...
...
...

procedure prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
var
  SC_OKC: TClientSocket;
  procedure prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
  begin
      //
  end;
begin
  try
      SC_OKC := TClientSocket.Create(_AForm);
      SC_OKC.ClientType := ctNonBlocking;
      SC_OKC.Address := '127.0.0.1';
      SC_OKC.Port := 35782;
      SC_OKC.OnWrite := prc_SC_OKCWrite;
      SC_OKC.Active := True;
      ...
      ...
      ...
      SC_OKC.Active := False;
      SC_OKC.Free;
      SC_OKC := nil;
  except
       //
  end;
end;

[ertank]

Merhaba,

Sizin atama yapmak istediğiniz nesne bir sınıf (class) içinde tanımlı ve siz form içinde tanımlı "pointer procedure" e atama yapmak istiyorsunuz. Bu ikisi türleri farklı olduğu için birbirinin yerine kullanılamaz. Dolayısı ile atama yapmak istediğiniz prosedürü ya TForm içinde tanımlayacaksınız ya da TEntitys içinde tanımlayacaksınız.

Ancak TEntitys tanımlarınızda bir eksiklik var. procedure tanımlarının başına "class" ifadesini eklemeniz gerekiyor. Böylece Delphi bu tanımların "pointer procedure" olmadığını anlayacaktır. Kodunuzu aşağıdaki şekilde değiştirirseniz çalışacaktır.

TEntitys tanımı:

Kod: Tümünü seç

Type
  TEntitys = class
  private
    class procedure prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
  public
    class procedure prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
  end;

Atama yapılacak private prosedür:

Kod: Tümünü seç

class procedure TEntitys.prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
begin
    //
end;

TEntitys public procedure:

Kod: Tümünü seç

class procedure TEntitys.prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
var
  SC_OKC: TClientSocket;
begin
  try
    SC_OKC := TClientSocket.Create(_AForm);
    SC_OKC.ClientType := ctNonBlocking;
    SC_OKC.Address := '127.0.0.1';
    SC_OKC.Port := 35782;
    SC_OKC.OnWrite := prc_SC_OKCWrite;
    SC_OKC.Active := True;
    SC_OKC.Active := False;
    SC_OKC.Free;
    SC_OKC := nil;
  except
    //
  end;
end;

Bu noktada bir iki konuda dikkatinizi çekmek isterim.
1- Değişken tanımlama her ne kadar programcının kendi tasarrufunda olsa da programlama dilinin kabul görmüş genel kullanımlarına uymakta her zaman fayda vardır. Aşağıdaki birkaç örnek değişken isimi yerine alternatif önerileri kullanmanız hem okumasını hemde yazmasını kolaylaştıracaktır.

prc_SC_OKCWrite yerine prcScOkcWrite
_AForm yerine Form veya AForm
_iId yerine Iid


2- SC_OKC değişkenini aşağıdaki şekilde kullanmanızda fayda var. Aksi halde örnek kod bir hata oluşması durumunda hafıza kaçağına sebep olacaktır.

Kod: Tümünü seç

SC_OKC := TClientSocket.Create(_AForm);
try
  SC_OKC.ClientType := ctNonBlocking;
  SC_OKC.Address := '127.0.0.1';
  SC_OKC.Port := 35782;
  SC_OKC.OnWrite := prc_SC_OKCWrite;
  SC_OKC.Active := True;
  SC_OKC.Active := False;
finally
  FreeAndNil(SC_OKC);
end;

Eğer kullanıcıdan saklamak istediğiniz bir hata varsa bunu sadece ilgili bölümü try..except bloğu içine alarak yapmanız daha iyi olur.

[adelphiforumz]

ertank hocam benim amacım aynı procedure altında tüm tanımlamaları yaparak bir bütün halinde kullanmaya çalıştım
eğer global tanımlama ile yaparsam zaten sorun olmuyor.
kusura bakmayın sanırım sorunu eksik anlatmışım.

[ertank]

Bildiğim kadarıyla yapmak istediğinizi ancak TEntitys sınıfını kullanmazsanız yapabilirsiniz.

[adelphiforumz]

ertank hocam zaten ilk bahsettiğim örnekte bu sınıfı kullanmadanyapmaya çalışmıştım fakat hata almıştım nasıl olacağı konusunda bir fikriniz varmı
teşekkürler

[ertank]

Aşağıdaki gibi Form içi prosedürler tanımlayarak yapabilirsiniz.

Kod: Tümünü seç

unit Unit1;

interface

uses
  Windows,
  Messages,
  SysUtils,
  Variants,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
  ScktComp;

type
  TForm1 = class(TForm)
    ClientSocket1: TClientSocket;
  private
    { Private declarations }
    procedure prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
    procedure prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
begin
  //
end;

procedure TForm1.prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
var
  SC_OKC: TClientSocket;
begin
  SC_OKC := TClientSocket.Create(_AForm);
  try
    SC_OKC.ClientType := ctNonBlocking;
    SC_OKC.Address := '127.0.0.1';
    SC_OKC.Port := 35782;
    SC_OKC.OnWrite := prc_SC_OKCWrite;
    SC_OKC.Active := True;
    SC_OKC.Active := False;
  finally
    FreeAndNil(SC_OKC);
  end;
end;

end.

[adelphiforumz]

ertank hocam

Dediğiniz gibi zaten yapılabiliyor.
Benim öğrenmeye çalıştığım bir Procedure içerisinde tüm tanımlamaları yaparak bu iş yapılabilirmi.
Yani type class yapısını aynı procedure içinde yapmama izin verirmi verirse nasıl yapılabilir.
Teşekkürler

Mesela aşağıdaki gibi birşey olabilirmi

Kod: Tümünü seç

procedure prcX;
type
  Tx = class
  public
      procedure prcY(.....);
   ...
  private
end;
var
   Evn : Tx;
begin
  Evn := TX;
...
...
  OnEvent...    := Evn.PrcY; 
end;

[ertank]

İlk mesajımın ilk paragrafında neden olmayacağını yazmaya çalışmıştım. Sizin yapmak istediğiniz şekilde tanımlanan prosedürler "pointer procedure" oluyor. Ancak Bir olaya atama yapmak istediğiniz zaman "method procedure" atayabiliyorsunuz. İkisi Delphi için farklı şeyler ve bildiğim kadarı ile birbirinin yerine kullanımı mümkün değil.

Sonuç olarak, ya TEntitys sınıfı içinde tüm tanımlamaları yapıp kullanacaksınız. Ya da TForm1 sınıfı içinde. İki alternatiften birisini seçmeniz gerekiyor.

[csunguray]

Fakat derlemede hata alıyorum

Hata mesajını da yazsaydınız keşke.

[adelphiforumz]

csunguray aldığım hata mesajıda aşağıdaki şekildedir

Hata mesajını da yazsaydınız keşke.

mesajın alındığı satır
SC_OKC.OnWrite := prc_SC_OKCWrite;

Hata mesajı
[dcc32 Error] untEntitys.pas(310): E2009 Incompatible types: 'method pointer and regular procedure'

Umarım bu yazdıklarımla çözüme ulaştırabilirsiniz.
Teşekkürler

[kimimben]

Kod: Tümünü seç

procedure TEntitys.prc_Socket_Yazdir(_AForm:TForm; _iId: Integer);
var
  SC_OKC: TClientSocket;
  m : TMethod;

  procedure prc_SC_OKCWrite(Sender: TObject; Socket: TCustomWinSocket);
  begin
    ShowMessage('test');
  end;
begin

  m.Data := nil;
  m.Code := @prc_SC_OKCWrite;
  try
      SC_OKC := TClientSocket.Create(_AForm);
      SC_OKC.OnWrite := TSocketNotifyEvent(m);
      //SC_OKC.OnWrite(nil,nil);
      SC_OKC.ClientType := ctNonBlocking;
      SC_OKC.Address := '127.0.0.1';
      SC_OKC.Port := 35782;
      SC_OKC.Active := True;
      SC_OKC.Active := False;
      SC_OKC.Free;
      SC_OKC := nil;
  except on E: Exception do

  end;

end;

[adelphiforumz]

Selam "kimimben" hocam
tamda istediğim buydu ellerine emeğine sağlık
teşekkürler

[kimimben]

Selam "kimimben" hocam
tamda istediğim buydu ellerine emeğine sağlık
teşekkürler

Aleykümselam.
Rica ederim çok bir emek harcamadım.
method pointer and regular procedure hatasını araştırdıktan sonra, gelen ilk linkte ki Ondrej Kelle'nin cevabını uyguladım.

[ertank]

Öğrenmenin sonu yok.