görev cubuğunun yeri ve yüksekliği

[skyking]

slm arkadaslar görev cubugunun yerinin yukarda ,asagıda, sagda ,solda oldugunu nasıl anlıyabilirim birde yüksekliği?

[skyking]

taskbar ın yüksekliği

Kod: Tümünü seç

function TaskBarHeight: integer;
var
  hTB: HWND; // taskbar handle
  TBRect: TRect; // taskbar rectangle
begin
  hTB:= FindWindow('Shell_TrayWnd', '');
  if hTB = 0 then
    Result := 0
  else begin
    GetWindowRect(hTB, TBRect);
    Result := TBRect.Bottom - TBRect.Top;
    end;
end;

taskbar gizlimi

Kod: Tümünü seç

function IsTaskbarAutoHideOn : boolean;
var
  ABData : TAppBarData;
begin
  ABData.cbSize := sizeof(ABData);
  Result :=
    (SHAppBarMessage(ABM_GETSTATE, ABData)
     and ABS_AUTOHIDE) > 0;
end;

taskbarın konumu

Kod: Tümünü seç

type
  TTaskBarPos = (_TOP, _BOTTOM, _LEFT, _RIGHT, _NONE);

function GetTaskBarPos: TTaskBarPos;
var
  hTaskbar: HWND;
  T: TRect;
  scrW, scrH: integer;
begin
  hTaskBar := FindWindow('Shell_TrayWnd', nil);
  if hTaskbar <> 0 then
  begin
    GetWindowRect(hTaskBar, T);
    ScrW := Screen.Width;
    ScrH := Screen.Height;
    if (T.Top > scrH div 2) and (T.Right >= scrW) then
      Result := _BOTTOM
    else if (T.Top < scrH div 2) and (T.Bottom <= scrW div 2) then
      Result := _TOP
    else if (T.Left < scrW div 2) and (T.Top <= 0) then
      Result := _LEFT
    else // the last "if" is not really needed
    if T.Left >= ScrW div 2 then
      Result := _RIGHT;
  end;
end;

örnek

Kod: Tümünü seç

procedure TForm1.Button1Click(Sender: TObject);
var
  tabd: TAppBarData;
  PosString: string;
begin
  FillChar(tabd, SizeOf(TAppBarData), 0);
  tabd.cbSize := SizeOf(TAppBarData);
  if SHAppBarMessage(ABM_GETTASKBARPOS, Tabd) = 0 then Exit;
  with Tabd.rc do
    PosString := Format(' (%d, %d);(%d, %d) ', [Left, Top, Right, Bottom]);
  case tabd.uEdge of
    ABE_LEFT: ShowMessage('Left Position' + PosString);
    ABE_TOP: ShowMessage('Top Position' + PosString);
    ABE_RIGHT: ShowMessage('Right Position' + PosString);
    ABE_BOTTOM: ShowMessage('Bottom Position' + PosString);
  end;
end;

procedure TForm1.Button5Click(Sender: TObject);
var
  TaskBarPos: TTaskBarPos;
begin
  TaskBarPos := GetTaskBarPos;
  case TaskBarPos of
    _LEFT: ShowMessage('Left Position');
    _TOP: ShowMessage('Top Position');
    _RIGHT: ShowMessage('Right Position');
    _BOTTOM: ShowMessage('Bottom Position');
  end;
end;

[comfort]

Çok lazım olmuştu bulamamıştım ellerine sağlık